const std = @import("std");

fn StackList(comptime T: type, comptime capacity_type: type, comptime capacity: capacity_type) type {
    return struct {
        const Self = @This();
        mem: [capacity]T,
        length: capacity_type,

        fn add(self: *Self, value: T) void {
            self.mem[self.length] = value;
            self.length += 1;
        }

        fn has(self: *Self, needle: T) bool {
            for (0..self.length) |i| {
                if (self.mem[i] == needle) {
                    return true;
                }
            }

            return false;
        }

        fn getMutableSlice(self: *Self) []T {
            return (&self.mem)[0..self.length];
        }

        fn getSlice(self: *const Self) []const T {
            return self.mem[0..self.length];
        }

        fn init() Self {
            return Self{
                .mem = undefined,
                .length = 0,
            };
        }
    };
}

fn tilt(lines: [][]u8) void {
    var column: usize = 0;
    while (column < lines[0].len) : (column += 1) {
        var row: usize = 0;
        var first_empty_row: usize = std.math.maxInt(usize);
        while (row < lines.len) : (row += 1) {
            switch (lines[row][column]) {
                '#' => {
                    first_empty_row = std.math.maxInt(usize);
                },
                '.' => {
                    if (first_empty_row > row) {
                        first_empty_row = row;
                    }
                },
                'O' => {
                    if (first_empty_row < row) {
                        lines[first_empty_row][column] = 'O';
                        lines[row][column] = '.';
                        first_empty_row += 1;
                    }
                },
                else => unreachable,
            }
        }
    }
}

fn solveLines(lines: [][]u8) usize {
    tilt(lines);

    var result: usize = 0;

    var row: usize = 0;
    while (row < lines.len) : (row += 1) {
        const weight = lines.len - row;
        const line = lines[row];
        var column: usize = 0;
        while (column < line.len) : (column += 1) {
            switch (line[column]) {
                '#' => {},
                '.' => {},
                'O' => {
                    result += weight;
                },
                else => unreachable,
            }
        }
    }
    return result;
}

pub fn solveAll(reader: anytype) !usize {
    var result: usize = 0;
    while (true) {
        var allocator_buffer: [10000]u8 = undefined;
        var fba = std.heap.FixedBufferAllocator.init(&allocator_buffer);
        var allocator = fba.allocator();

        var lines = StackList([]u8, usize, 100).init();
        var empty_line_reached = false;

        var line_buffer: [1000]u8 = undefined;
        while (try reader.readUntilDelimiterOrEof(&line_buffer, '\n')) |line| {
            if (line.len == 0) {
                empty_line_reached = true;
                break;
            }
            lines.add(try allocator.dupe(u8, line));
        }

        result += solveLines(lines.getMutableSlice());

        if (!empty_line_reached) {
            return result;
        }
    }
}

pub fn main() !void {
    const stdout = std.io.getStdOut().writer();

    const raw_in = std.io.getStdIn();
    var buffered_reader = std.io.bufferedReader(raw_in.reader());
    var reader = buffered_reader.reader();
    const result = try solveAll(&reader);
    try stdout.print("{d}\n", .{result});
}